Пакетная замена и добавление 1 к числу между определенным текстом в XML-файле

Сначала давайте кратко рассмотрим ваши попытки:

1. терпит неудачу, так как ищет только 10 и вообще не учитывает теги <LastSerialNumber>.
2. терпит неудачу, потому что вы пытаетесь определить строку для опции delims= для for /F, хотя на самом деле она определяет набор символов.
3. терпит неудачу, потому что вы пытаетесь перенаправить (>) в переменную, которая не может работать, вы можете перенаправить только в файлы. Кроме того, вы пытаетесь выполнить арифметику (+1), но это работает только при использовании set /A. И последний раздел имеет ту же проблему, что и подход 1.

Вот как вы можете это сделать:

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem // Define constants here:
set "_FILE=%~1" & rem // (input file; `%~1` is the first argument)
set "_TAG=<LastSerialNumber>" & rem // (opening tag)

rem // Loop over all (non-empty) lines of the input file:
for /F "usebackq delims=" %%L in ("%_FILE%") do (
    rem // Store current line string:
    set "LINE=%%L"
    rem // Toggle delayed expansion to avoid troubles with `!`:
    setlocal EnableDelayedExpansion
    rem // Split off opening tag from line string:
    set "TEST=!LINE:*%_TAG%=!"
    rem // Check whether opening tag has been found:
    if not "!TEST!"=="!LINE!" (
        rem // Opening tag found, hence split off closing tag:
        for /F "tokens=1* eol=< delims=< " %%S in ("!TEST!") do (
            rem // Get extracted number and increment it:
            set /A "NUM=%%S+1"
            rem // Return rebuild line with incremented number:
            echo(  !_TAG!!NUM!^<%%T
        )
    ) else (
        rem // Opening tag not found, hence return original line:
        echo(!LINE!
    )
    endlocal
)

endlocal
exit /B

Учитывая, что пакетный файл называется inc-serial.bat, вызовите его с входным файлом XML в качестве аргумента командной строки (скажем, test.xml в текущем каталоге):

inc-serial.bat "test.xml"

Чтобы записать вывод в другой файл, используйте перенаправление (>):

inc-serial.bat "test.xml" > "test_NEW.xml"

Хорошо, наконец-то я получил код, который работает так, как мне нужно. Просто нужно установить каталоги, которые я оставил здесь по понятным причинам. Большое спасибо aschipfl за помощь. Этот код индексирует серийный номер на единицу, записывает во временный файл, затем выполняет обратную запись и удаляет временный файл. Затем отображает новый серийный номер.

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem // Define constants here:
set "_FILE=BatchTest.xml" & rem // (input file; `%~1` is the first argument)
set "_TAG=<LastSerialNumber>" & rem // (opening tag)

rem // Loop over all (non-empty) lines of the input file:
(for /F "usebackq delims=" %%L in ("%_FILE%") do (
    rem // Store current line string:
    set "LINE=%%L"
    rem // Toggle delayed expansion to avoid troubles with `!`:
    setlocal EnableDelayedExpansion
    rem // Split off opening tag from line string:
    set "TEST=!LINE:*%_TAG%=!"
    rem // Check whether opening tag has been found:
    if not "!TEST!"=="!LINE!" (
        rem // Opening tag found, hence split off closing tag:
        for /F "tokens=1* eol=< delims=< " %%S in ("!TEST!") do (
            rem // Get extracted number and increment it:
            set /A "NUM=%%S+1"
        rem // Return rebuild line with incremented number:
            echo(  !_TAG!!NUM!^<%%T
        )
    ) else (
        rem // Opening tag not found, hence return original line:
        echo(!LINE!
    )
    endlocal
))>BatchTestTmp.xml 


copy /v /y "BatchTestTmp.xml" "BatchTest.xml" & cls

del "BatchTestTmp.xml"

set "LINE=4"
(for /f "usebackq delims=" %%a in (`more +%LINE% BatchTest.xml`) DO (
set result=%%a
setlocal EnableDelayedExpansion
echo Your Serial Number is !result:~20,2!
pause 
goto :leave
))
:leave
endlocal

exit /B

Впечатляет то, что старый добрый Batch все еще может решить эту проблему. Очевидно, что он не предназначен для поддержки XML, поэтому я бы порекомендовал инструмент, который изначально поддерживает его с помощью выражений XPath/XQuery, например xidel.

Часть ECHO проста:

xidel -s input.xml -e "concat('Your serial number is ',//LastSerialNumber,' where ',//LastSerialNumber + 1,' is the new number')"
Your serial number is 10 where 11 is the new number

Редактировать немного сложнее:

xidel -s input.xml --xquery "serialize(transform(/,function($x){$x/(if (name()='LastSerialNumber') then <LastSerialNumber>{node() + 1}</LastSerialNumber> else .)}),{'omit-xml-declaration':false()})"
<?xml version="1.0" encoding="UTF-8"?>
<BatchSettings>
  <SerialFormat>{0:yyMMdd}{1:00}</SerialFormat>
  <LastSerialDate>2020-05-27T00:00:00-05:00</LastSerialDate>
  <LastSerialNumber>11</LastSerialNumber>
</BatchSettings>

- transform() перебирает каждый элемент-узел. Он оставляет каждый из них нетронутым, за исключением случаев, когда он находит <LastSerialNumber>. Затем он создает новый с исходным значением + 1.
- serialize() упорядочивает вывод, а с помощью {'omit-xml-declaration':false()} добавляет сверху объявление xml.

serialize() просто выводит вывод (на стандартный вывод). Чтобы записать вывод в файл, используйте file:write(). вместо:

xidel -s input.xml --xquery "file:write('input.xml',transform(/,function($x){$x/(if (name()='LastSerialNumber') then <LastSerialNumber>{node() + 1}</LastSerialNumber> else .)}),{'omit-xml-declaration':false()})"

Чтобы объединить это с частью ECHO:

xidel -s input.xml --xquery "concat('Your serial number is ',//LastSerialNumber,' where ',//LastSerialNumber + 1,' is the new number'),file:write('input.xml',transform(/,function($x){$x/(if (name()='LastSerialNumber') then <LastSerialNumber>{node() + 1}</LastSerialNumber> else .)}),{'omit-xml-declaration':false()})"

Предварительный запрос (с необходимыми escape-символами):

xidel -s input.xml --xquery ^"^
  concat(^
    'Your serial number is ',^
    //LastSerialNumber,^
    ' where ',^
    //LastSerialNumber + 1,^
    ' is the new number'^
  ),^
  file:write(^
    'input.xml',^
    transform(^
      /,^
      function($x){^
        $x/(^
          if (name()='LastSerialNumber') then^
            ^<LastSerialNumber^>{node() + 1}^</LastSerialNumber^>^
          else^
            .^
        )^
      }^
    ),^
    {'omit-xml-declaration':false()}^
  )^
"

Это напечатает Your serial number is 10 where 11 is the new number и редактирует (и перезаписывает) 'input.xml'.

[edit]
{'omit-xml-declaration':false()} работает только с Xidel 0.9.9 (начиная с xidel-0.9.9.20190104.6739.b64562007cb7). В Xidel 0.9.8 вы можете вручную добавить xml-декларацию:

xidel -s input.xml --xquery "concat('Your serial number is ',//LastSerialNumber,' where ',//LastSerialNumber + 1,' is the new number'),file:write('input.xml',('<?xml version=\"1.0\" encoding=\"UTF-8\"?>',transform(/,function($x){$x/(if (name()='LastSerialNumber') then <LastSerialNumber>{node() + 1}</LastSerialNumber> else .)})))"

[/править]