KDB+\q: Как заполнить периодические временные ряды?

Один из способов сделать это — создать вторичную пустую таблицу с той же схемой, где во втором столбце указаны все отсутствующие моменты времени. Для этого создайте список всех интересующих вас моментов времени. Один из способов сделать это — взять первый и последний элемент и сделать следующее:

q)f:exec first second from t
q)f
02:46:01
q)l:exec last second from t
q)l
02:46:05
q)s:f+`second$til 1+`long$l-f
q)s
02:46:01 02:46:02 02:46:03 02:46:04 02:46:05

Обратите внимание, что второй тип должен быть приведен к типу long для работы с функцией til, а затем приведен обратно ко второму типу. Также мы добавляем 1, чтобы последний раз (02:46:05) не был пропущен.

Мы можем создать пустую таблицу с той же схемой, выполнив следующие действия:

q)et:select by second:s from 0#t
q)et
second  | amount price
--------| ------------
02:46:01|
02:46:02|
02:46:03|
02:46:04|
02:46:05|

0# — это быстрый способ создать пустую таблицу с той же схемой, что и исходная таблица t. Теперь lj можно использовать для объединения двух таблиц, а fills будет пересылать любые пустые значения:

q)et lj t
second  | amount price
--------| -------------
02:46:01| 54     9953.5
02:46:02|
02:46:03|
02:46:04| 150
02:46:05|        9954.5
q)fills et lj t
second  | amount price
--------| -------------
02:46:01| 54     9953.5
02:46:02| 54     9953.5
02:46:03| 54     9953.5
02:46:04| 150    9953.5
02:46:05| 150    9954.5

Здесь у вас действительно есть два отдельных шага: заполнение нулевых значений в вашей таблице и создание временного ряда с регулярными интервалами из вашей таблицы.

У вас уже есть средства для заполнения нулевых значений. Чтобы сгенерировать временной ряд, вы можете использовать функцию присоединение по состоянию.

Учитывая вашу (уже заполненную) таблицу

q)show t:([second:02:46:01 02:46:04 02:46:05]amount:45 150 150;price:9953.5 9953.5 9954.5)
second  | amount price
--------| -------------
02:46:01| 45     9953.5
02:46:04| 150    9953.5
02:46:05| 150    9954.5

вы можете создать временной ряд, сначала определив вспомогательную таблицу с желаемыми шагами расчета

q)show ts:([]second:02:46:01+til 5)
second
--------
02:46:01
02:46:02
02:46:03
02:46:04
02:46:05

а затем при объединении этих двух таблиц

q)aj[`second;ts;t]
second   amount price
----------------------
02:46:01 45     9953.5
02:46:02 45     9953.5
02:46:03 45     9953.5
02:46:04 150    9953.5
02:46:05 150    9954.5

Вы можете легко расширить этот метод для создания таких временных рядов, когда ваша таблица содержит несколько инструментов.