Схема Монте-Карло-Сэмплинг

Я написал решение этой проблемы в моем блоге; внутренняя функция называется sand, потому что я бросал песчинки вместо шариков:

(define (pi n)
    (define (sand?) (< (+ (square (rand)) (square (rand))) 1))
    (do ((i 0 (+ i 1)) (p 0 (+ p (if (sand?) 1 0))))
        ((= i n) (exact->inexact (* 4 p (/ n))))))

Это очень медленно сходится; после ста тысяч итераций у меня было 3.14188. В записи блога также обсуждается метод оценки числа Пи, разработанный Архимедом за двести лет до Рождества Христова, который очень быстро сходится: 27 итераций подводят нас к арифметике с двойной точностью.

Ваши круглые скобки перепутаны, и ваш порядок аргументов для < неверен. Вот как должен выглядеть код после исправления:

(define (monte-carlo-sampling n)
  (let ((x (- (* 2 (random)) 1))
        (y (- (* 2 (random)) 1)))
    (cond ((= n 0)
           0)
          (else
           (cond ((< (sqrt (+ (square x) (square y))) 1)
                  (+ 1 (monte-carlo-sampling (- n 1))))
                 (else
                  (monte-carlo-sampling (- n 1))))))))

Это возвращает количество совпадений. Вам нужно будет преобразовать количество совпадений в оценку числа Пи, используя внешнюю функцию, например:

(define (estimate-pi n)
  (* 4 (/ (monte-carlo-sampling n) n)))

Вот как бы я все это написал, если бы мне было поручено:

(define (estimate-pi n)
  (let loop ((i 0)
             (hits 0))
    (cond ((>= i n)
           (* 4 (/ hits n)))
          ((<= (hypot (sub1 (* 2 (random)))
                      (sub1 (* 2 (random)))) 1)
           (loop (add1 i) (add1 hits)))
          (else
           (loop (add1 i) hits)))))

(Проверено на Racket с использованием определения hypot, которое я дал в моем последнем ответе. Если вы не используете Racket, вам нужно изменить add1 и sub1 на что-то подходящее.)

Вот общий метод выполнения монте-карло, который он принимает в качестве аргументов количество итераций и thunk (процедура без аргументов), который должен возвращать #t или #f, который является экспериментом, который будет запускаться на каждой итерации.

(define (monte-carlo trials experiment)
  (define (iter trials-remaining trials-passed)
    (cond ((= trials-remaining 0)
           (/ trials-passed trials))
          ((experiment)
           (iter (- trials-remaining 1) (+ trials-passed 1)))
          (else
           (iter (- trials-remaining 1) trials-passed))))
  (iter trials 0))

Теперь осталось написать конкретный эксперимент.

Вы можете написать в своем эксперименте, где эксперимент запускается в Монте-Карло, но абстрагирование здесь дает вам гораздо более гибкую и понятную функцию. Если вы заставляете функцию делать слишком много вещей одновременно, становится трудно обдумывать и отлаживать.

(define (marble-experiment)
 (let ((x ...)  ;;assuming you can come up with 
       (y ...)) ;;a way to get a random x between 0 and 1
                ;;with sufficient granularity for your estimate)
  (< (sqrt (+ (* x x) (* y y))) 1)))

(define pi-estimate
  (* 4 (monte-carlo 1000 marble-experiment)))