Эликсир: Десятичное приведение и не допускаются отрицательные числа

Как я упоминал в своем последнем комментарии, Decimal — это другой тип, который больше, чем целые числа.

К счастью, Decimal предоставляет функции gt?, lt? и compare, которые можно использовать для сравнения Decimal с целыми числами. Несколько чистым решением, чтобы изменить ваш код как можно меньше, было бы добавить небольшую дополнительную функцию перед handle_cast и другое определение для handle_cast. Что-то вроде этого:

defp operation(%Account{balance: balance}, value, operation) do
  value
  |> Decimal.cast()
  |> maybe_positive?()
  |> handle_cast(balance, operation)
end

defp maybe_positive?({:ok, value}) do
  case Decimal.compare?(value, 0) do
    :lt -> {:error, :negative_number}
    :gt -> {:ok, value}
  end
end

defp maybe_positive?(error), do: error

defp handle_cast({:error, :negative_number}, _balance, _operation) do
  {:error, "Number must be positive"}
end
defp handle_cast({:ok, value}, balance, :deposit), do: Decimal.add(balance, value)
...

Таким образом, если это отрицательное число, оно проходит проверку {:error, :negative_number} из handle_cast, а если оно положительное или cast по какой-то причине не удалось, оно проходит другие проверки handle_cast, которые у вас уже есть.

Хотя ответ @sbacarob совершенно правильный, я бы опубликовал его для удобства.

Decimal — это простая структура, поэтому можно использовать его внутренности для обработки негативов с охраной. Это будет работать с современными версиями Elixir ≥ 1.11 и OTP ≥ 23.

defguard is_decimal_positive(value)
    when is_map(value) and
         value.__struct__ == Decimal and 
         value.sign == 1

Подробнее см. Kernel.defguard/1. И использовать его как

defp operation(%Account{balance: balance}, value, operation) do
  value
  |> Decimal.cast()
  |> handle_cast(balance, operation)
end

defp handle_cast({:ok, value}, balance, _) 
    when is_decimal_positive(value),
  do: Decimal.add(balance, value)

defp handle_cast(_error, _balance, _),
  do: {:error, "Number must be positive decimal"}

Ta fazendo или NLW de ELixir tambem! Eu fiz assim e funcionou:

Репозиторий: https://github.com/librity/nlw_elixir

defmodule Rocketpay.Accounts.Operation do
  alias Ecto.Multi
  alias Rocketpay.Account

  def call(%{"id" => id, "value" => value}, operation) do
    fetch_account_operation_name = build_fetch_account_operation_name(operation)

    Multi.new()
    |> Multi.run(
      fetch_account_operation_name,
      fn repo, _previous -> fetch_account(repo, id) end
    )
    |> Multi.run(operation, fn repo, fetch_result ->
      account = Map.get(fetch_result, fetch_account_operation_name)

      update_balance(repo, account, value, operation)
    end)
  end

  defp fetch_account(repo, id) do
    case repo.get(Account, id) do
      nil -> {:error, "Account not found."}
      account -> {:ok, account}
    end
  end

  defp update_balance(repo, account, value, operation) do
    account
    |> calculate_new_balance(value, operation)
    |> update_account(account, repo)
  end

  defp calculate_new_balance(%Account{balance: balance}, value, operation) do
    value
    |> Decimal.cast()
    |> validate_greater_than_zero()
    |> handle_cast(balance, operation)
  end

  defp validate_greater_than_zero({:ok, casted_value}) do
    case Decimal.compare(casted_value, 0) do
      :lt -> :error
      :eq -> :error
      :gt -> {:ok, casted_value}
    end
  end

  defp validate_greater_than_zero(:error), do: :error

  defp handle_cast({:ok, valid_value}, balance, :deposit), do: Decimal.add(balance, valid_value)
  defp handle_cast({:ok, valid_value}, balance, :withdraw), do: Decimal.sub(balance, valid_value)

  defp handle_cast(:error, _balance, :deposit), do: {:error, "Invalid deposit value."}
  defp handle_cast(:error, _balance, :withdraw), do: {:error, "Invalid withdraw value."}

  defp update_account({:error, _reason} = error, _account, _repo), do: error

  defp update_account(new_balance, account, repo) do
    account
    |> Account.changeset(%{balance: new_balance})
    |> repo.update()
  end

  defp build_fetch_account_operation_name(operation),
    do: "fetch_#{operation}_account" |> String.to_atom()
end