Настройка пропуска знаков препинания при перемещении слов вперед и назад

Я тоже считаю, что мне хотелось бы, чтобы движение было более инклюзивным, чем w, но не таким инклюзивным, как W. В частности, я хотел бы движение, которое считает важными только токены, начинающиеся с буквенно-цифровых символов.

Итак, я придумал следующее:

" <SPACE>   : forward to next word beginning with alphanumeric char
" <S-SPACE> : backward to prev word beginning with alphanumeric char
" <C-SPACE> : same as above (as <S-SPACE> not available in console Vim
" <BS>      : back to prev word ending with alphanumeric char
function! <SID>GotoPattern(pattern, dir) range
    let g:_saved_search_reg = @/
    let l:flags = "We"
    if a:dir == "b"
        let l:flags .= "b"
    endif
    for i in range(v:count1)
        call search(a:pattern, l:flags)
    endfor
    let @/ = g:_saved_search_reg
endfunction
nnoremap <silent> <SPACE> :<C-U>call <SID>GotoPattern('\(^\\|\<\)[A-Za-z0-9_]', 'f')<CR>
vnoremap <silent> <SPACE> :<C-U>let g:_saved_search_reg=@/<CR>gv/\(^\\|\<\)[A-Za-z0-9_]<CR>:<C-U>let @/=g:_saved_search_reg<CR>gv
nnoremap <silent> <S-SPACE> :<C-U>call <SID>GotoPattern('\(^\\|\<\)[A-Za-z0-9_]', 'b')<CR>
vnoremap <silent> <S-SPACE> :<C-U>let g:_saved_search_reg=@/<CR>gv?\(^\\|\<\)[A-Za-z0-9_]<CR>:<C-U>let @/=g:_saved_search_reg<CR>gv
nnoremap <silent> <BS> :call <SID>GotoPattern('[A-Za-z0-9_]\(\>\\|$\)', 'b')<CR>
vnoremap <silent> <BS> :<C-U>let g:_saved_search_reg=@/<CR>gv?[A-Za-z0-9_]\(\>\\|$\)<CR>:<C-U>let @/=g:_saved_search_reg<CR>gv

" Redundant mapping of <C-SPACE> to <S-SPACE> so that
" above mappings are available in console Vim.
"noremap <C-@> <C-B>
if has("gui_running")
    map <silent> <C-Space> <S-SPACE>
else
    if has("unix")
        map <Nul> <S-SPACE>
    else
        map <C-@> <S-SPACE>
    endif
endif

У меня это было уже давно, и я обнаружил, что использую <SPACE>/<C-SPACE> движения, поэтому гораздо чаще, чем w и W; это просто кажется более полезным при кодировании. Конечно, вы можете сопоставить команды с любыми клавишами, которые вы считаете полезными или более подходящими.

Даже рискуя создать сценарий для чего-то встроенного (, как я в последний раз), вот небольшая функция, которая может помочь в этом.

function! JumpToNextWord()
    normal w
    while strpart(getline('.'), col('.')-1, 1) !~ '\w'
        normal w
    endwhile
endfunction

По сути, он выполняет стандартный w и повторяет его, если символ под курсором не является символом слова (не стесняйтесь изменять этот шаблон.

Если вы добавите это и небольшую карту в свой .vimrc:

nnoremap <silent> ,w :call JumpToNextWord()<CR>

Он должен работать.